CU Amiga Super CD-ROM 23/CU Amiga - Super CD-ROM 23 (June 1998).iso/CUCD/Graphics/STIMP_noise/Install

Text File | 1998-02-24 | 5.6 KB | 247 lines

;
; Skript zur Installation von STIMP_noise 1.01
; inklusive Unterstuetzung fuer Ultraconv
; Version 1.02, 24.02.98
; (c) 1998 Stefan Diener
;

(set @pretend 0)
(set @user-level 2)
(set @default-dest "")

(complete 0)

(if (= @language "deutsch")
 (
   ; deutsche Textausgaben
   (set #yes "Ja")
   (set #no "Nein")
   (set #gruss "\n\n\n\nSTIMP_noise 1.01\n© 1997/98 by Stefan Diener\n\n\nWillkommen zur Installation von STIMP_noise 1.01 !\nDieses Skript wird STIMP_noise auf Ihrer Festplatte installieren.\n")
   (set #destimsg "Wo wollen Sie STIMP_noise installieren ?\n(Ein Verzeichnis namens STIMP wird dort automatisch erzeugt.)")
   (set #addlines "\nZwei Zeilen müssen zur Datei S:User-Startup hinzugefügt werden:\n")
   (set #fertig "\nSTIMP_noise ist nun auf Ihrer Festplatte in folgendem\nVerzeichnis installiert:\n")
   (set #whichcpu "Für welche CPU sollen optimierte Versionen\ninstalliert werden ?")
   (set #reallyuconv "Möchten Sie die Programme auch von\nUltraconv aus benutzen ?")
 )
 (
   ; english text output
   (set #yes "Yes")
   (set #no "No")
   (set #gruss "\n\n\n\nSTIMP_noise 1.01\n© 1997/98 by Stefan Diener\n\n\nWelcome to the STIMP_noise 1.01 installation !\nThis script will install STIMP_noise on your harddisk.\n")
   (set #destimsg "Where do you want to install STIMP_noise ?\n(A directory called STIMP will be automaticly created.)")
   (set #addlines "\nTwo lines have to be added to your S:User-Startup:\n")
   (set #fertig "\nSTIMP_noise is now installed on your harddisk at:\n")
   (set #whichcpu "For which CPU shall I install an optimised version ?")
   (set #reallyuconv "Do you want to use the programs\ntogether with Ultraconv too ?")
 )
)


; kleine Begruessung
(message #gruss
)

; Zielpfad ermitteln
(set #destidir
  (askdir
    (prompt #destimsg)
    (help @askdir-help)
    (default "GFX:")
  )
)

(complete 10)

(set #dstdir
  (tackon #destidir "STIMP")
)

; ggf. Verzeichnis fuer STIMP erst erzeugen
(if (= (exists #dstdir) 0)
 (makedir #dstdir)
)

(complete 20)

; alle Pfade definieren
(set #binpath
  (tackon #dstdir "bin")
)

(set #docpath
  (tackon #dstdir "doc")
)

(set #helppath
  (tackon #dstdir "help")
)

(set #sourcepath
  (tackon #dstdir "source")
)

; Dokumentation kopieren
(copyfiles
  (source "doc")
  (dest #docpath)
  (pattern "#?")
)

(complete 30)

; Help-Dateien kopieren
(copyfiles
  (source "help")
  (dest #helppath)
  (pattern "#?")
)

(complete 40)

; Quelltexte kopieren
(copyfiles
  (source "source")
  (dest #sourcepath)
  (pattern "#?")
)

(complete 60)

(set #linetoadd1
  (cat "Assign STIMP: " #dstdir)
)

(set #linetoadd2 "Assign C: STIMP:bin add")

; Assign-Zeilen in S:User-Startup einfuegen
(startup "STIMP"
  (prompt #addlines
          #linetoadd1 "\n"
          #linetoadd2)
  (help "These lines have to be added in order to make the STIMP programs run properly !")
  (command #linetoadd1 "\n" #linetoadd2)
)

; auch jetzt schon Assign wirksam werden lassen
(makeassign "STIMP" #dstdir)

; hier muesste stehen: "Assign C: STIMP:bin add",
; wurde aber in S:User-Startup eingefuegt und ist
; nach einem Neustart verfuegbar ...
; (makeassign "C" "STIMP:bin")

(complete 70)

; automatische Auswahl der CPU
(set #mycpu (database "cpu"))
(if (= #mycpu 68000) (set #cpu 0))
(if (= #mycpu 68010) (set #cpu 0))
(if (= #mycpu 68020) (set #cpu 0))
(if (= #mycpu 68030) (set #cpu 1))
(if (= #mycpu 68040) (set #cpu 1))
(if (= #mycpu 68060) (set #cpu 1))

; Benutzer nach optimaler Programmvariante fragen
(set #cpuver (askchoice (choices "68000" "68030+68882" "PowerPC")
               (prompt #whichcpu)
               (help   "The 68000 versions will work on all Amigas.\n"
                       "If you have a MC68030 (or higher) with FPU,\nuse the 68030+68882 versions !\n"
                       "If you are so lucky owning a PPC, select it !\n")
               (default #cpu)
             )
)

(complete 80)

; jeweilige Programmvariante kopieren
(if (= #cpuver 0)
  ; also nur 68000
  (copyfiles
    (source "bin")
    (dest #binpath)
    (pattern "#?")
  )
)

(if (= #cpuver 1)
  ; doch schon 68030+68882
  (copyfiles
    (source "bin.030882")
    (dest #binpath)
    (pattern "#?")
  )
)

(if (= #cpuver 2)
  ; wow, PowerPC
  (copyfiles
    (source "bin.ppc")
    (dest #binpath)
    (pattern "#?")
  )
)

(complete 90)


; Ultraconv-Unterstuetzung erwuenscht ?
(set #uconv (askchoice (choices #yes #no)
              (prompt #reallyuconv)
              (help "If you are a registered user of Ultraconv, I suggest to select YES !")
              (default 0)
            )
)

(if (= #uconv 0)
  ; Ultraconv-Unterstuetzung ist erwuenscht !
  ; this is a little bit more complicated,
  ; so I give it up to a shell script

  (if (< (getversion "UConv:Ultraconv") 196608)
    (
      ; noch nicht V3, also muss Zahl der Filter neu berechnet werden

      (if (= #cpuver 0)
        ; also nur 68000
        (execute "Ultraconv/AddNewFilters.Skript")
      )

      (if (= #cpuver 1)
        ; doch schon 68030+68882
        ; trotzdem wie beim 68000
        (execute "Ultraconv/AddNewFilters.Skript")
      )

      (if (= #cpuver 2)
        ; wow, PowerPC
        (execute "Ultraconv/AddNewFilters.Skript.ppc")
      )
    )
    (
      ; mindestens V3, also nur Joinen von zwei Dateien

      (if (= #cpuver 0)
        ; also nur 68000
        (execute "Ultraconv/AddNewFilters.Skript.V3")
      )

      (if (= #cpuver 1)
        ; doch schon 68030+68882
        ; trotzdem wie beim 68000
        (execute "Ultraconv/AddNewFilters.Skript.V3")
      )

      (if (= #cpuver 2)
        ; wow, PowerPC
        (execute "Ultraconv/AddNewFilters.Skript.V3.ppc")
      )
    )
  )
)

(complete 100)

; das war es schon -> Verabschiedung
(message #fertig #dstdir "\n\n\nHave fun !"
)